SmartRestrict -- класс для контроля ввода пользователя

Класс SmartRestrict предназначен для обслуживания тех случаев, когда необходимо заставить пользователя ввести в определенное текстовое поле определенную строку и для контроля этого процесса. Подобные задачи возникают, например, в интерактивных презентациях и обучающих приложениях. Преставьте, что вам нужно научить пользователя вводить правильный логин и пароль при входе в систему:

Пример использования:

import com.flashripper.utils.SmartRestrict;


function onTextResult(res){

	trace("Success:" + res);

}

// создаем экземпляр класса SmartRestrict, 

// в качестве параметров указывая  текстовое поле, 

// строку, которую необходимо заставить ввести пользователя, 

// функцию-обработчик результата 

// и максимально допустимое кол-во неудачных попыток, 

// после совершения которых приложение само 

// заполнит текcтовое поле нужным значением

sr=new SmartRestrict(txtLogin, "login", onTextResult,5);

Исходный код класса:

// SmartRestrict class v 0.5.0.1 by Rostislav Siryk

// Usage: new SmartRestrict(txtFieldToRestrict:TextField, strToBeEntered:String, fncOnResult:Function, numErrorsMaxCount:Number)


import mx.utils.Delegate;

class com.flashripper.utils.SmartRestrict {

	static private var dc=Delegate.create;

	

	private var txtField:TextField;

	private var strToEnter:String=String("Unknown");

	private var strInProgress:String=String("");

	private var numCharIndex:Number=Number(0); 

	private var numAttempts:Number=Number(0); 

	private var numAttemptsMax:Number=Number(24);

	private var fncOnResponse:Function;

	

	public function SmartRestrict(txtFieldToRestrict:TextField, strToBeEntered:String, fncOnResult:Function, numErrorsMaxCount:Number)

	{

		strToEnter=strToBeEntered;

		txtField=txtFieldToRestrict;

		fncOnResponse=fncOnResult;

		if(numErrorsMaxCount) numAttemptsMax=numErrorsMaxCount;

		//txtField.restrict=strToEnter;

		txtField.onChanged=dc(this,onRestricted);

		Selection.setFocus(txtField);

	}

	

	private function onRestricted()

	{

		var numCharEntered=Key.getAscii();

		var numCharNeeded=strToEnter.charCodeAt(numCharIndex);

		trace(numCharEntered + "-" + numCharNeeded + "/"+numAttempts);

		if(numCharEntered==numCharNeeded)

		{

			strInProgress+=strToEnter.charAt(numCharIndex);

			numCharIndex++;

		}else{

			numAttempts++;

		}

		txtField.text=strInProgress;

		if(numAttempts>numAttemptsMax || strToEnter==strInProgress)

		{

			doFinalize();

		}

	}

	

	private function doFinalize()

	{

		txtField.text=strToEnter;

		txtField.onChanged=null;

		txtField.type="dynamic";

		fncOnResponse(strToEnter==strInProgress);

		delete this;

	}

}